股票选股公式和技术指标记录

SJY发表于:2018年05月29日 13:38 • 阅读:

首先是我个人的均线设置习惯

周线:5、10、30、70

其他全部:5、10、20、60

技术指标

我用过的技术指标,有些已经不实用,但思路可以扩展,改成适合自己的

大盘走势,我用在同花顺,用来对比个股与大盘

DRAWKLINE(INDEXH,INDEXO,INDEXL,INDEXC);

自定义K线,同花顺。盘后模拟日线没走完时的价格。D是位置,S是价格

当前位置:BARPOS;
CC:=C;
HH:=H;
IF(BARPOS==D){
CC:=S;
IF(CC>O)HH:=CC;
IF(CC<O)HH:=O;
}
DRAWKLINE(HH,O,L,CC);
MA5:MA(CC,5);
MA10:MA(CC,10);

5日均线乖离率,股价收盘价和最低价距离5日均线的距离,当时认为这两者接近5日均线容易上涨。

M5:=MA(CLOSE, 5);
CG:=(CLOSE/M5-1)*100;
LG:=(LOW/M5-1)*100;
COND:=M5>REF(M5,1) AND CLOSE>M5 AND CG<2 AND LG>-2;
收盘价乖离率:CG;
最低价乖离率:LG;
STICKLINE(COND,CG,LG,10,1),colorgreen;

5日均线力度,5日均线走缓原趋势变弱,走强原趋势变强

MA5:=MA(CLOSE,5);
MA10:=MA(CLOSE,10);
MA20:=MA(CLOSE,20);
五日线力度:MA5-REF(MA5,1);
COND:=MA10>REF(MA10,1) AND MA5<REF(MA5,1) AND 五日线力度>REF(五日线力度,1);
DRAWTEXT(COND,五日线力度,'准备');
DRAWICON(REF(COND,1) AND MA5>REF(MA5,1),五日线力度,1);

选股公式

吴迪的五弯十,我写在同花顺里

M5:=MA(CLOSE, 5);
M10:=MA(CLOSE, 10);
M20:=MA(CLOSE, 20);
M60:=MA(CLOSE, 60);
M250:=MA(CLOSE, 250);
乖离率:ABS(M5-M10)/M10*100;

COND:=M10>REF(M10,1) AND M20>REF(M20,1) AND CLOSE>M20 AND //10日线和20日线必须坚挺,才能保证在上升趋势中 股价不能跌破20日线,就算是回调也不能跌破,否则就不再强势
M5>M60 AND M5>M250 AND //5日线最起码过60日线才较强势,过250日线才可能长期上涨,实在选不出来时去掉过250日线的条件
REF(M5,1)<REF(M5,2) AND 乖离率<N;//至少昨天是下弯的 没有下弯过就没有五弯十一说;5日线和10日线的距离必须足够小,才能触发五弯十

SELECT COND;

首次突破5日均量线和均价线,容易起爆

VMA5:=MA(VOL,5);
MA5:=MA(CLOSE,5);
A1:=VOL>VMA5;
A2:=CLOSE>MA5;
COUNT(A1,N)=1 AND A1 AND COUNT(A2,N)=1 AND A2;

股价靠近5日均线,同花顺。当时认为靠近5日线容易起爆

M5:=MA(CLOSE,5);
CG:=(CLOSE/M5-1)*100;
LG:=(LOW/M5-1)*100;
M10:=MA(CLOSE,10);
R:=M5>M10 AND M5>REF(M5,1) AND CLOSE>M5 AND CG<1 AND LG>-2;
SELECT R;

次新股,同花顺。在行情不好时,次新股往往表现不错。

yxq:=BARSCOUNT(CLOSE);
yxq>15 AND yxq<250;

均线成本价接近,价格最高的均线和价格最低的均线,他们之间距离几个点。用来选均线粘合的股票。M是乖离率,N是天数

M10:=MA(CLOSE,10);
M55:=MA(CLOSE,55);
M120:=MA(CLOSE,120);
M250:=MA(CLOSE,250);
JUNX_MAX:=MAX(M10,MAX(M55,MAX(M120,M250)));
JUNX_MIN:=MIN(M10,MIN(M55,MIN(M120,M250)));
长短期均线乖离率:=(JUNX_MAX-JUNX_MIN)/JUNX_MIN*100;
COUNT(长短期均线乖离率<M,N)>0 AND M5>JUNX_MAX;

精髓

首次符合某个条件

方法一

M20:=MA(CLOSE,20);
REF(EVERY(M20<REF(M20,1),20),1) AND M20>REF(M20,1);{过去20天的20日均线始终是下弯的 今天刚上翘}

方法二

M10:=MA(CLOSE,10);
A1:=CLOSE>M10;
COUNT(A1,20)=1 AND A1;{20天里收盘价大于10日均线的只有1天,且就是当天}

 

欢迎转载,但请保留原文地址 http://www.sjyhome.com/articles/stock-selection-formula-and-technical-indicator.html

回复(0)